[EasyUo]Magery

Magery:


;==================================
; Script Name: snicker7's UNMOVING MAGERY.
; Author: snicker7
; Version: 100,000.1
; Client Tested with: 4.0.6a
; EUO version tested with: 1.42.009D
; Shard OSI / FS: FS
; Revision Date: 11/25/04
; Public Release: 11/25/05
; Global Variables Used:
; Purpose: Train magery without moving for freeshards.
;==================================
set %warmode 0 ;edit by atu (Thanx @atu)

chooseskill mage
set %startingskill #skill
set %currentskill #skill
if %currentskill < 300 2
display ok You need greater than 30.0 Magery to start this script.
halt

gosub showmenu
gosub dressInit

loop:
gosub choosespell
gosub cast
goto loop:

sub choosespell
if %currentskill <= 1000
{
set %spell 56
set %manatocast 50
set %castdelay 40
set %masochistic 0
menu delete currentspell
menu text currentspell 68 55 Earthquake
}
if %currentskill < 890
{
set %spell 52
set %manatocast 40
set %castdelay 48
set %masochistic 0
menu delete currentspell
menu text currentspell 68 55 Mana Vampire
}
if %currentskill < 740
{
set %spell 43
set %manatocast 20
set %castdelay 48
set %masochistic 0
menu delete currentspell
menu text currentspell 68 55 Invis
}

if %currentskill < 600
{
set %spell 38
set %manatocast 15
set %castdelay 48
set %masochistic 0
menu delete currentspell
menu text currentspell 68 55 Poisonfield
}
}
if %currentskill < 500
{
set %spell 29
set %manatocast 11
set %castdelay 43
set %masochistic 1
menu delete currentspell
menu text currentspell 68 55 Lightning
}
set %healspell 28
if %currentskill < 50
set %healspell 3
return

sub cast
If %spell = 56 ;edit by atu
gosub warmode
gosub openhealthbar
if %masochistic = 1
gosub checkhealth
gosub checkmana %manatocast
recast:
event macro 15 %spell
target 3s
if %masochistic = 2
{
set #ltargetx 206 ;#charposx - 2
set #ltargety 1377 ;#charposy
set #ltargetz 7 ;#charposz
set #ltargetkind 3
set #ltargettile 1197
event macro 22 0
}
else
{
; set #ltargetid #charid
; set #ltargetkind 1
event macro 23 0
}
wait 5
gosub checkskill
wait %castdelay
return

sub checkskill
chooseskill mage
if #skill > %currentskill
{
set %currentskill #skill
sound
str len %currentskill
str ins %currentskill #dot #strRes
menu delete currentskill
menu text currentskill 68 25 #strRes
set %totalgains %currentskill - %startingskill
str len %totalgains
str ins %totalgains #dot #strRes
menu delete totalgains
menu text totalgains 68 40 #strRes
}
return

sub checkhealth
gosub openhealthbar
checkhealth:
if #hits = #maxhits
return
set %healat #maxhits - ( #maxhits / 5 )
if #hits < %healat
{
gosub checkmana 11
event macro 15 %healspell
target 3s
event macro 23 0
goto checkhealth
}
return

sub checkmana
manacheckloop:
if #mana > %1
{
if %undressed = #true
gosub dressLrc
return
}
if %undressed = #false
gosub undressLrc
event macro 13 46
set %medstart #scnt
wait 10
for %i 1 2
{
scanjournal %i
if meditative in #journal
goto manaloopmain
}
wait:
if #scnt < %medstart + 11 2
wait 1
goto wait
goto manacheckloop
manaloopmain:
if #mana < #maxmana 2
wait 1
goto manaloopmain
if %undressed = #true
gosub dressLrc
return

sub dressInit
set %dressWait 100
gosub dressLrc init
set %dressedCnt #findcnt
gosub undressLrc init
set %undressedCnt #findcnt
set %dressWait ( %dressedCnt - %undressedCnt ) * 11
return

sub dressLrc
dress:
key f11
wait %dressWait
finditem * C_ , #charid
if ( %0 = 0 ) && ( #findcnt < %dressedCnt )
goto dress
set %undressed #false
return

sub undressLrc
undress:
key f12
wait %dressWait
finditem * C_ , #charid
if ( %0 = 0 ) && ( #findcnt > %undressedCnt )
goto undress
set %undressed #true
return

sub openhealthbar
if #charname = N/A
{
event macro 8 2
wait 10
}
return

sub warmode ;edit by atu
If %warmode = 0
{
repeat
{
msg # , warmode$
wait 2
scanjournal 1
}
until Warmode_OFF in #journal || Du_bist_kein_Young in #journal
set %warmode 1
}
return


sub showmenu
menu clear
menu window title Unmoving Magery
menu window size 180 95
menu window color black
menu font name arial
menu font size 12
menu font color Red
menu font bgcolor black
menu text title 5 5 UNMOVING MAGERY.
menu font size 8
menu font color lime
menu text mageryskill 5 25 Current skill:
menu text gains 5 40 Total gains:
menu text casting 5 55 Casting:
menu font color green
str len %currentskill
str ins %currentskill #dot #strRes
menu delete currentskill
menu text currentskill 68 25 #strRes
set %totalgains %currentskill - %startingskill
str len %totalgains
str ins %totalgains #dot #strRes
menu delete totalgains
menu text totalgains 68 40 #strRes
menu font align right
menu text credit 176 80 by snicker7.
menu font align left
menu show
return